FileMgr

✏️ /usr/src/linux-headers-6.8.0-136/scripts/coccinelle/free/put_device.cocci

✕ Tutup

// SPDX-License-Identifier: GPL-2.0
/// Find missing put_device for every of_find_device_by_node.
///
// Confidence: Moderate
// Copyright: (C) 2018-2019 Wen Yang, ZTE.
// Comments:
// Options: --no-includes --include-headers

virtual report
virtual org

@search exists@
local idexpression id;
expression x,e,e1;
position p1,p2;
type T,T1,T2,T3;
@@

id = of_find_device_by_node@p1(x)
... when != e = id
if (id == NULL || ...) { ... return ...; }
... when != put_device(&id->dev)
    when != platform_device_put(id)
    when != if (id) { ... put_device(&id->dev) ... }
    when != e1 = (T)id
    when != e1 = (T)(&id->dev)
    when != e1 = get_device(&id->dev)
    when != e1 = (T1)platform_get_drvdata(id)
(
  return
(    id
|    (T2)dev_get_drvdata(&id->dev)
|    (T3)platform_get_drvdata(id)
|    &id->dev
);
| return@p2 ...;
)

@script:python depends on report@
p1 << search.p1;
p2 << search.p2;
@@

coccilib.report.print_report(p2[0],
                             "ERROR: missing put_device; call of_find_device_by_node on line "
                             + p1[0].line
                             + ", but without a corresponding object release within this function.")

@script:python depends on org@
p1 << search.p1;
p2 << search.p2;
@@

cocci.print_main("of_find_device_by_node", p1)
cocci.print_secs("needed put_device", p2)

Batal

⬅ coccinelle 9 item

Nama	Tipe	Ukuran	Diubah	Perm	Aksi
📄 clk_put.cocci	cocci	1.3 KB	10/03/24 20:38	0644	✏️ ⬇
📄 devm_free.cocci	cocci	2.5 KB	10/03/24 20:38	0644	✏️ ⬇
📄 ifnulldev_put.cocci	cocci	1.1 KB	10/03/24 20:38	0644	✏️ ⬇
📄 ifnullfree.cocci	cocci	1.3 KB	10/03/24 20:38	0644	✏️ ⬇
📄 iounmap.cocci	cocci	1.3 KB	10/03/24 20:38	0644	✏️ ⬇
📄 kfree.cocci	cocci	1.8 KB	10/03/24 20:38	0644	✏️ ⬇
📄 kfreeaddr.cocci	cocci	646 B	10/03/24 20:38	0644	✏️ ⬇
📄 pci_free_consistent.cocci	cocci	1.3 KB	10/03/24 20:38	0644	✏️ ⬇
📄 put_device.cocci	cocci	1.3 KB	10/03/24 20:38	0644	✏️ ⬇

✏️ Rename

🔑 Ubah Permission