FileMgr

✏️ /usr/share/doc/gawk/examples/network/coreserv.awk

✕ Tutup

# CGI Library and core of a web server
#
# Juergen Kahrs, Juergen.Kahrs@vr-web.de
# with Arnold Robbins, arnold@skeeve.com
# September 2000

# Global arrays
#   GETARG --- arguments to CGI GET command
#   MENU   --- menu items (path names)
#   PARAM  --- parameters of form x=y

# Optional variable MyHost contains host address
# Optional variable MyPort contains port number
# Needs TopHeader, TopDoc, TopFooter
# Sets MyPrefix, HttpService, Status, Reason

BEGIN {
  if (MyHost == "") {
     "uname -n" | getline MyHost
     close("uname -n")
  }
  if (MyPort ==  0) MyPort = 8080
  HttpService = "/inet/tcp/" MyPort "/0/0"
  MyPrefix    = "http://" MyHost ":" MyPort
  SetUpServer()
  while ("awk" != "complex") {
    # header lines are terminated this way
    RS = ORS    = "\r\n"
    Status      = 200             # this means OK
    Reason      = "OK"
    Header      = TopHeader
    Document    = TopDoc
    Footer      = TopFooter
    if        (GETARG["Method"] == "GET") {
        HandleGET()
    } else if (GETARG["Method"] == "HEAD") {
        # not yet implemented
    } else if (GETARG["Method"] != "") {
        print "bad method", GETARG["Method"]
    }
    Prompt = Header Document Footer
    print "HTTP/1.0", Status, Reason     |& HttpService
    print "Connection: Close"            |& HttpService
    print "Pragma: no-cache"             |& HttpService
    len = length(Prompt) + length(ORS)
    print "Content-length:", len         |& HttpService
    print ORS Prompt                     |& HttpService
    # ignore all the header lines
    while ((HttpService |& getline) > 0)
        continue
    # stop talking to this client
    close(HttpService)
    # wait for new client request
    HttpService |& getline
    # do some logging
    print systime(), strftime(), $0
    CGI_setup($1, $2, $3)
  }
}

function CGI_setup(method, uri, version,    i)
{
    delete GETARG
    delete MENU
    delete PARAM
    GETARG["Method"] = method
    GETARG["URI"] = uri
    GETARG["Version"] = version

i = index(uri, "?")
    if (i > 0) {  # is there a "?" indicating a CGI request?
        split(substr(uri, 1, i-1), MENU, "[/:]")
        split(substr(uri, i+1), PARAM, "&")
        for (i in PARAM) {
            PARAM[i] = _CGI_decode(PARAM[i])
            j = index(PARAM[i], "=")
            GETARG[substr(PARAM[i], 1, j-1)] = \
                                         substr(PARAM[i], j+1)
        }
    } else { # there is no "?", no need for splitting PARAMs
        split(uri, MENU, "[/:]")
    }
    for (i in MENU)     # decode characters in path
        if (i > 4)      # but not those in host name
            MENU[i] = _CGI_decode(MENU[i])
}
function _CGI_decode(str,   hexdigs, i, pre, code1, code2,
                            val, result)
{
   hexdigs = "123456789abcdef"

i = index(str, "%")
   if (i == 0) # no work to do
      return str

do {
      pre = substr(str, 1, i-1)   # part before %xx
      code1 = substr(str, i+1, 1) # first hex digit
      code2 = substr(str, i+2, 1) # second hex digit
      str = substr(str, i+3)      # rest of string

code1 = tolower(code1)
      code2 = tolower(code2)
      val = index(hexdigs, code1) * 16 \
            + index(hexdigs, code2)

result = result pre sprintf("%c", val)
      i = index(str, "%")
   } while (i != 0)
   if (length(str) > 0)
      result = result str
   return result
}

Batal

⬅ examples 24 item

Nama	Tipe	Ukuran	Diubah	Perm	Aksi
⚙️ PostAgent.sh	sh	274 B	17/11/22 16:36	0644	✏️ ⬇
📄 catpipeclient.awk	awk	156 B	17/11/22 16:36	0644	✏️ ⬇
📄 catpipeserver.awk	awk	209 B	17/11/22 16:36	0644	✏️ ⬇
📄 coreserv.awk	awk	3.3 KB	17/11/22 16:36	0644	✏️ ⬇
📄 daytimeclient.awk	awk	231 B	17/11/22 16:36	0644	✏️ ⬇
📄 daytimeserver.awk	awk	83 B	17/11/22 16:36	0644	✏️ ⬇
📄 eliza.awk	awk	10 KB	17/11/22 16:36	0644	✏️ ⬇
📄 fingerclient.awk	awk	232 B	17/11/22 16:36	0644	✏️ ⬇
📄 geturl.awk	awk	787 B	17/11/22 16:36	0644	✏️ ⬇
📄 hello-serv.awk	awk	463 B	17/11/22 16:36	0644	✏️ ⬇
📄 mailpopclient.awk	awk	503 B	17/11/22 16:36	0644	✏️ ⬇
📄 maze.awk	awk	2.6 KB	17/11/22 16:36	0644	✏️ ⬇
📄 mobag.awk	awk	2.8 KB	17/11/22 16:36	0644	✏️ ⬇
📄 panic.awk	awk	575 B	17/11/22 16:36	0644	✏️ ⬇
📄 protbase.awk	awk	400 B	17/11/22 16:36	0644	✏️ ⬇
📄 protbase.request	request	162 B	17/11/22 16:36	0644	✏️ ⬇
📄 protbase.result	result	642 B	17/11/22 16:36	0644	✏️ ⬇
📄 remconf.awk	awk	2.1 KB	17/11/22 16:36	0644	✏️ ⬇
📄 statist.awk	awk	3.5 KB	17/11/22 16:36	0644	✏️ ⬇
📝 stoxdata.txt	txt	165 B	17/11/22 16:36	0644	✏️ ⬇
📄 stoxpred.awk	awk	5.5 KB	17/11/22 16:36	0644	✏️ ⬇
📄 testserv.awk	awk	334 B	17/11/22 16:36	0644	✏️ ⬇
📄 urlchk.awk	awk	1 KB	17/11/22 16:36	0644	✏️ ⬇
📄 webgrab.awk	awk	187 B	17/11/22 16:36	0644	✏️ ⬇

✏️ Rename

🔑 Ubah Permission